1. SWF 파일이 있는 도메인(서버)과 다른 도메인(서버)에 XML 파일과 이미지파일이 있는 경우.

var url:URLRequest = new URLRequest("http://www.AAA.com/data.xml");
var loader:Loader = new Loader();
loader.load(url);

위의 소스로 문제없이 이미지파일이 로드된다.

2. SWF 파일이 있는 도메인(서버)에 XML 파일이 있고 다른 도메인(서버)에 이미지파일이 있는 경우.

이 경우 1번에서 사용한 소스로는 이미지파일이 로드되지 않는다.
이유는, LoaderContext 클래스를 매개변수로 전달하지 않아서인데…
아래 소스로 수정하면 이미지파일이 로드된다.

var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = true;
var url:URLRequest = new URLRequest("http://www.BBB.com/data.xml");
var loader:Loader = new Loader();
loader.load(url, context);

//AS 2.0
String.prototype.addCommas = function() {
	var _length = this.length;
	var _str = "";
	for (var i = 0; i <= _length; ++i) {
		_str = this.charAt(_length - i) + _str;
		if (i % 3 == 0 && i > 0 && i < _length) {
			_str = "," + _str;
		}
	}
	return (_str);
};

str = "1234567890";
trace(str.addCommas());

//Output
//1,234,567,890

//AS 3.0
function addCommas(_string:String):String{
	var _len = _string.length;
	var _str = "";
	for (var i = 0; i <= _len; ++i) {
		_str = _string.charAt(_len - i) + _str;
		if (i % 3 == 0 && i > 0 && i < _len) {
			_str = "," + _str;
		}
		//trace(_str);
	}
	return (_str);
}

trace(addCommas("1234567890"));

//Output
//1,234,567,890

폰트를 임베드하기 위해서는 위의 3가지 방법이 있는데,
무슨 이유인지는 모르겠지만, TTF파일을 경로를 통해 임베드하는 위의 두 방법을 사용하면 에러가… FD라서 그런건가;;
암튼, 3번째 시스템폰트의 이름을 사용해서 임베드하는 방법은 아무 문제없이 클리어~
일단, 잊어버리지 않기 위해 메모!!!

package {

	import flash.display.MovieClip;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;
	import flash.text.AntiAliasType;

	[SWF(width = "600", height = "240", backgroundColor = "#FFFFFF", framerate = "30")]

	public class Main extends MovieClip {

		//[Embed(source = '../lib/CONSOLA.TTF', fontName = "Font", mimeType = "application/x-font-truetype")]
		//[Embed(source = 'C:\WINDOWS\Fonts\CONSOLA.TTF', fontName = "Font", mimeType = "application/x-font-truetype")]
		[Embed(systemFont = 'Consolas', fontName = "Font", mimeType = "application/x-font-truetype")]

		public var font:Class;

		public function Main() {
			var format:TextFormat = new TextFormat();
			format.font	= "Font";
			format.color = 0x333333;
			format.size = 80;
			format.letterSpacing = -2;

			var label:TextField = new TextField();
			label.embedFonts = true;
			label.autoSize = TextFieldAutoSize.LEFT;
			label.antiAliasType = AntiAliasType.ADVANCED;
			label.defaultTextFormat = format;
			label.text = "blog.flasia.com";
			addChild(label);

			label.rotation = 10;
		}
	}
}

if (ExternalInterface.available) {
	var locationUrl:String = ExternalInterface.call("document.location.href.toString");
	if (locationUrl != null) {
		var urlVars:Array = locationUrl.split("?");
		var urlParam:Array = String(urlVars[1]).split("&");
	}
}

urlVars[1]에는 ?뒤의 부분(varA=0123&varB=abcd)이 들어가게 된다.
그리고 urlParam에는 “&” 를 기준으로 나눠진 항목이 배열로 저장된다.(varA=0123, varB=abcd)
이제, 이 배열을 적절히 사용하면 끝~

이럴 경우,

if (e.keyCode == 229) {
	IME.conversionMode = IMEConversionMode.ALPHANUMERIC_HALF;
}

로 영문입력모드로 전환해준다.

참고 : AS3.0 ランダムにテキストを表示させてみる

// RandomText.as
package {
	import flash.display.MovieClip;
	import flash.events.TimerEvent;
	import flash.utils.Timer;
	import flash.display.StageScaleMode;
	import flash.display.StageAlign;
	import flash.events.Event;
	import flash.text.TextField;

	public class RandomText {

		private var txtNum:int;
		private var tf:TextField;
		private var txt:String; //인수의 문자열을 담을 변수
		private var rightTxt:String;//1글자씩 표시하는 변수
		private var fakeTxt:String = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890!@%&$#_?!/-";
		private var timer:Timer;
		private var viewTrace:Boolean;

		public function RandomText(_tf:TextField, _txt:String, _time:uint = 50, _viewTrace:Boolean = false):void {
			tf = _tf;
			txt = _txt;
			timer = new Timer(_time);
			viewTrace = _viewTrace;
		}

//////////////////////////////////////////////////////////////////시작
		public function start():void {
			txtNum = 0;
			rightTxt = ""; //1글자씩 대입되는 변수
			tf.addEventListener(Event.ENTER_FRAME, rollWord); //랜덤하게 표시
			timer.addEventListener(TimerEvent.TIMER, endTimer);
			timer.start();
		}

//////////////////////////////////////////////////////////////////랜덤하게 글자를 표시
		private function rollWord(e:Event):void {
			tf.text = rightTxt;
			//랜덤하게 글자를 표시하는 글자수
			var randomTextNum:int = txt.length - rightTxt.length;
			for (var i:int = 0; i < randomTextNum; i++) {
				var randNum:Number = Math.floor(Math.random()*fakeTxt.length);
				tf.appendText(fakeTxt.charAt(randNum));
			}
		}

//////////////////////////////////////////////////////////////////타이머
		private function endTimer(e:Event):void {
			if (txtNum != txt.length - 1) {
				rightTxt += txt.charAt(txtNum);
				txtNum += 1;
				if (viewTrace) {
					trace(txtNum);
				}
			}
			else { //타이머종료
				tf.text = txt;
				tf.removeEventListener(Event.ENTER_FRAME, rollWord);
				timer.stop();
			}
		}

//////////////////////////////////////////////////////////////////
	}
}

// Main.as
package {

	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;

	public class Main extends Sprite{
		public function Main():void {
			var _tf:TextField = new TextField();
			_tf.defaultTextFormat = new TextFormat("Verdana", 12, 0x000000);
			_tf.background = true;
			_tf.backgroundColor = 0xE0E0E0;
			_tf.autoSize = TextFieldAutoSize.LEFT;
			_tf.selectable = false;
			_tf.text = "";
			_tf.x = 10;
			_tf.y = 10;
			addChild(_tf);

			var rt:RandomText = new RandomText(_tf, "ActionScript Thread Library 1.0 (そうめん) ドキュメント", 25);
			rt.start();
		}
	}
}

DynamicEvent 클래스를 이용하는 방법.
먼저 DynamicEvent 클래스를 작성합니다.

package {
    import flash.events.Event;

    public dynamic class DynamicEvent extends Event {
        public function DynamicEvent(type:String,
                                     bubbles:Boolean = false,
                                     cancelable:Boolean = false) {
            super(type, bubbles, cancelable);
        }

        override public function clone():Event {
            return new DynamicEvent(type, bubbles, cancelable);
        }
    }
}

Flex SDK에는 mx.events.DynamicEvent 이라는 클래스가 정의되어 있기 때문에 Flex SDK로 개발하는 경우 이 클래스를 사용하는 것이 좋을지도…

송신은 이렇게~

var event:DynamicEvent = new DynamicEvent("myEvent");
event.param1 = "문자열";
event.param2 = [1, 2, 3];  // 배열도OK
dispatchEvent(event);

dispatchEvent(event);

수신은 이렇게~

addEventListener("myEvent", function(event:DynamicEvent):void {
    trace(event.param1); // 문자열
});

button.addEventListener(MouseEvent.CLICK, function(e:MouseEvent) { handleClickEvent(e, "Home") } );

function handleClickEvent(e:MouseEvent, str:String) {
        trace("Argument :"+str,"- Event target :"+e.target.name);
}

오브젝트에 이벤트 리스너를 등록할 때 이벤트외의 인수를 함께 보내는 방법이다.
다른 이벤트에서도 사용 가능한지 하나하나 확인은 못 해봤지만,
MouseEvent에서 이상 없이 동작하는 걸로 봐서 다른 이벤트에서도 사용할 수 있을 것 같다.
잘만 사용하면 유용한 코드가 될지도…

package {

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;

	// SWF Metadata
	[SWF(width="400", height="300", backgroundColor="#FFFFFF", framerate="30")]

	public class Main extends Sprite {

		public function Main():void {
			var btn:Sprite = new Sprite();
			btn.graphics.clear();
			btn.graphics.beginFill(0x0099FF);
			btn.graphics.drawRect(0, 0, 100, 50);
			btn.graphics.endFill();

			btn.buttonMode = true;
			btn.x = stage.stageWidth * 0.5 - btn.width * 0.5;
			btn.y = stage.stageHeight * 0.5 - btn.height * 0.5;
			addChild(btn);

			btn.addEventListener(MouseEvent.CLICK, onClickHandler("0123456789"));
		}

		private function onClickHandler(value:String):Function {
			function myfunc(event:MouseEvent):void {
				trace(value);
				trace(event.target);
			}
			return myfunc;
		}
	}
}

//Output
//0123456789
//[object Sprite]

배열 내부에 중복된 요소가 있을 경우 중복된 요소를 제거하고 새로운 배열로 만들기

var testArray:Array = new Array("사과", "참외", "귤", "복숭아", "바나나", "귤", "배", "바나나", "참외");

function duplicateCheck(input_array:Array) {
	var result_array:Array = new Array();
	var tempStr:String = "";
	for (var i = 0; i < input_array.length; i++) {
		if (tempStr.search(input_array[i]) == -1) {
			//중복체크용 문자열에 값이 없으면 새로운 배열에 추가
			result_array.push(input_array[i]);
			tempStr += input_array[i] + " ";
			trace(input_array[i]);
		}
	}
	return result_array;
}

duplicateCheck(testArray);

//Output
//사과
//참외
//귤
//복숭아
//바나나
//배

search() 메서드

function search(pattern:*):int
지정된 pattern을 검색하고 일치하는 첫 번째 하위 문자열의 인덱스를 반환합니다. 일치하는 하위 문자열이 없으면 -1이 반환됩니다.

매개 변수
pattern:* — 비교할 패턴으로, 모든 유형의 객체가 될 수 있지만 일반적으로는 문자열 또는 일반 표현식입니다. pattern이 일반 표현식 또는 문자열이 아니면 문자열로 변환된 후 메서드가 실행됩니다. 일반 표현식을 지정한 경우 이 메서드는 일반 표현식의 전역 플래그("g") 및 lastIndex 속성을 무시합니다. 이 속성은 수정되지 않고 그대로 유지됩니다. 값을 전달하지 않거나 정의되지 않은 값을 전달하면 -1이 반환됩니다.

반환값
int — 일치하는 첫 번째 하위 문자열의 인덱스입니다. 일치 항목이 없으면 -1입니다. 이 문자열의 인덱스는 0부터 시작하므로 문자열에서 첫 번째 문자의 인덱스는 0이고 마지막 문자의 인덱스는 string.length - 1입니다.

라는 에러 문구를 종종 보게 되는데…
주로 클래스를 인스턴스화해서 addChild() 하면서 동시에 root, parent, stage 의 속성을 참조하려고 하면 위의 에러 문구를 만나게 된다. 이는 addChild()가 되었으니 당근 참조가 가능하겠지.. 라고 생각했는데, 결국 뒤통수를 맞게 되는 것이다.
(배구에서 공격하려고 점프했는데 공이 아직 안 올라온거라고 할까…)
여튼, 이럴 때 Event.ADDED_TO_STAGE 를 사용하면 간단히 해결된다.

package {

	import flash.display.MovieClip;
	import flash.events.Event;

	public class Main extends MovieClip {

		public function Main():void {
			addEventListener(Event.ADDED_TO_STAGE, onAddedHandler);
		}

		private function onAddedHandler(e:Event):void {
			init();
		}

		private function init():void {
			removeEventListener(Event.ADDED_TO_STAGE, onAddedHandler);

			trace( "stage.stageHeight : " + stage.stageHeight );
			trace( "stage.stageWidth : " + stage.stageWidth );
		}
	}
}

//CustomEventExam.as
package {

	import flash.events.Event;

	public class CustomEventExam extends Event {

		private var _customValue:Number;

		public function CustomEventExam(type:String, customValue:Number, bubbles:Boolean = false,
cancelable:Boolean = false) {
			super(type, bubbles, cancelable);
			_customValue = customValue;
		}

		public function get customValue():Number {
			return _customValue;
		}
	}
}

CustomEventExam 객체를 dispatchEvent 시킨다.

//EventDispatchExam.as
package {

	import flash.events.Event;
	import flash.events.EventDispatcher;

	public class EventDispatchExam extends EventDispatcher{

		public static const CUSTOM_EVENT:String = "custom_event";

		public function EventDispatchExam() {

		}

		public function callCustomEvent(n:Number):void {
			dispatchEvent(new CustomEventExam(CUSTOM_EVENT, n));
		}
	}
}

EventDispatchExam인스턴스를 생성하고, callCustomEvent()를 호출하면 CUSTOM_EVENT 가 이벤트리스너로 등록된 인스턴스에 이벤트와 인수를 전달, 해당 함수를 실행한다.

//Main.as
package {

	import flash.display.Sprite;
	import flash.events.Event;

	public class Main extends Sprite {

		public function Main():void{

			var myEvent:EventDispatchExam = new EventDispatchExam();

			myEvent.addEventListener(EventDispatchExam.CUSTOM_EVENT, onCustomEventFunc);
			myEvent.callCustomEvent(20);
		}		

		private function onCustomEventFunc(e:CustomEventExam):void {
			trace( "onCustomEventFunc" );
			trace( "e : " + e );
			trace( "e.target : " + e.target );
			trace( "e.customValue : " + e.customValue );
		}
	}
}

결과값

//OutPut
//onCustomEventFunc
//e : [Event type="custom_event" bubbles=false cancelable=false eventPhase=2]
//e.target : [object EventDispatchExam]
//e.customValue : 20

//EventDispatchExam.as
package {	

	import flash.events.Event;
	import flash.events.EventDispatcher;	

	public class EventDispatchExam extends EventDispatcher{

		public static const MY_EVENT:String = "my_event";
		public var _myEventValue:Number;

		public function EventDispatchExam() {
		}

		public function callMyEvent(n:Number):void {
			_myEventValue = n;
			dispatchEvent(new Event(MY_EVENT));
		}
	}
}

EventDispatchExam인스턴스를 생성하고, callMyEvent()를 호출하면 MY_EVENT 가 이벤트리스너로 등록된 인스턴스에 이벤트와 인수를 전달, 해당 함수를 실행한다.

//Main.as
package {

	import flash.display.Sprite;
	import flash.events.Event;

	public class Main extends Sprite {

		public function Main():void{
			var myEvent:EventDispatchExam = new EventDispatchExam();
			myEvent.addEventListener(EventDispatchExam.MY_EVENT, onMyEventFunc);
			myEvent.callMyEvent(10);
		}

		private function onMyEventFunc(e:Event):void {
			trace( "onMyEventFunc" );
			trace( "e : " + e );
			trace( "e.target : " + e.target );
			trace( "e.target._myEventValue : " + e.target._myEventValue );
		}
	}
}

결과값은 다음과 같다.

//OutPut
//onMyEventFunc
//e : [Event type="my_event" bubbles=false cancelable=false eventPhase=2]
//e.target : [object EventDispatchExam]
//e.target._myEventValue : 10

function dataSendLoad() {
	//변수를 PHP 파일로 전송할 개체 생성
	var mySendVars = new LoadVars();

	//개체에 변수 입력
	var mySendVars.sendvars = "testVars";

	//PHP로부터 보내진 변수들을 로드할 LoadVars 개체 생성
	var myLoadVars  = new LoadVars();

	//로드 완료 후 실행 할 함수 정의
	mySendVars.onLoad = function(success) {
		...
	}

	//PHP 파일로 변수 전송 및 로드
	mySendVars.sendAndLoad("send_load.php", myLoadVars, "POST");
}

AS 3.0에서는~~

package {

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.ProgressEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.net.URLRequestMethod;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLVariables;
	import flash.events.IOErrorEvent;

	public class Main extends Sprite {

		// 변수를 주고 받을 PHP파일
		private var url : String = "send_load.php";
		// PHP에 전달한 변수
		private var variables : URLVariables;			

		public function Main() : void {
			variables = new URLVariables();
			// 변수값 할당
			variables.sendvars = "testVars";		

			sendData(url, variables);
		}

		public function sendData(_url:String, _vars:URLVariables):void {
			var request : URLRequest = new URLRequest(_url);
			request.data = _vars;
			// 전송방식
			request.method = URLRequestMethod.POST;		

			var loader:URLLoader = new URLLoader();
			// 데이터 형식 지정(BINARY, TEXT, VARIABLES)
			loader.dataFormat = URLLoaderDataFormat.VARIABLES;
			loader.addEventListener(ProgressEvent.PROGRESS, onProgressHandler);
			loader.addEventListener(Event.COMPLETE, onCompleteHandler);
			loader.addEventListener(IOErrorEvent.IO_ERROR, onIOErrorHandler);
			loader.load(request);
		}

		private function onProgressHandler(e:ProgressEvent):void {
			trace("@ PHP Loading");
		}

		private function onCompleteHandler(e:Event):void {
			var loader : URLLoader = URLLoader(e.target);
			trace( "loader.data : " + loader.data );
		}

		private function onIOErrorHandler(e:IOErrorEvent):void {
			trace("Error loading URL.");
		}
	}
}

<script language="javascript">
if (AC_FL_RunContent == 0) {
alert("This page requires AC_RunActiveContent.js.");
} else {
AC_FL_RunContent(
'codebase', 'http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0',
'width', '400',
'height', '300',
'src', 'Example',
'quality', 'high',
'pluginspage', 'http://www.macromedia.com/go/getflashplayer',
'align', 'middle',
'play', 'true',
'loop', 'true',
'scale', 'showall',
'wmode', 'window',
'devicefont', 'false',
'id', 'Example',
'bgcolor', '#ffffff',
'name', 'Example',
'menu', 'true',
'allowFullScreen', 'false',
'allowScriptAccess','sameDomain',
'movie', 'Example',
'salign', ''
'FlashVars', 'myVar1=1&myVar2=2'
); //end AC code
}
</script>
<noscript>
<object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0" width="400" height="300" id="Example" align="middle">
<param name="allowScriptAccess" value="sameDomain" />
<param name="allowFullScreen" value="false" />
<param name="FlashVars" value="myVar1=1&myVar2=2" />
<param name="movie" value="Example.swf" />
<param name="quality" value="high" />
<param name="bgcolor" value="#ffffff" />
<embed src="Example.swf" quality="high" bgcolor="#ffffff" width="400" height="300" name="Example" align="middle" allowScriptAccess="sameDomain" allowFullScreen="false" type="application/x-shockwave-flash" pluginspage="http://www.macromedia.com/go/getflashplayer" />
</object>
</noscript>

플래시에서는 아래의 방법으로 변수를 사용~~

//AS 3.0
var myParam1 = loaderInfo.parameters.myVar1;
var myParam2 = loaderInfo.parameters.myVar2;

var myMC:MC1 = new MC1();
addChild(myMC);

그런데, 아래 이미지처럼 Linkage를 통해 Class를 지정해 준 놈이 많고, 게다가 Class이름이 일정한 규칙(MC1, MC2, MC3, …)을 갖고 있을 때,

요거 for문을 사용하면 먼가 될 거 같은 생각이 듭니다.
그런데, for문과 배열을 이용해서 변수를 규칙적으로 만들 수는 있지만 new연산자의 클래스를 각각 다르게 지정하는 건 안되죠..
요럴 때 getDefinitionByName()함수를 사용하면 편합니다.
레퍼런스에도 나와있지만

1.  Class유형의 변수 ClassReference를 getDefinitionByName()를 이용해서 원하는 클래스에 할당합니다.
2.  instance라는 ClassReference의 인스턴스를 인스턴스화 하고…
3.  원하는 속성값을 지정하고서 끄집어내면 됩니다.

for(var i:Number = 1; i <= 5; i++){
	var ClassReference:Class = getDefinitionByName("MC" + i) as Class;
	var instance:Object = new ClassReference();
	instance.x = 100 * i;
	instance.y = 50;
	instance.buttonMode = true;
	instance.name = "Circle" + i
	instance.addEventListener(MouseEvent.CLICK, onClickFunc);
	addChild(DisplayObject(instance));
}

function onClickFunc(e:MouseEvent):void{
	trace(e["target"].name);
}

package {

	import flash.display.Sprite;

	public class Main extends Sprite {

		private var circleNum:int = 20;
		private var sW:int = stage.stageWidth;
		private var sH:int = stage.stageHeight;
		private var radius:Number = 100;

		public function Main():void{
			var ary:Array = new Array(circleNum);
			for (var i:Number = 0; i < 20; i++) {
				ary[i] = new Sprite();
				ary[i].graphics.beginFill(Math.random() * 0xFFFFFF, Math.random());
				ary[i].graphics.drawCircle(Math.random() * sW, Math.random() * sH, Math.random() * radius);
				ary[i].graphics.endFill();
				ary[i].name = "Circle" + i;
				addChild(ary[i]);
			}
		}
	}
}

Case2
생성하려는 오브젝트의 갯수가 정해져 있지 않을 경우.

package {

	import flash.display.Sprite;

	public class Main extends Sprite {

		private var sW:int = stage.stageWidth;
		private var sH:int = stage.stageHeight;
		private var radius:Number = 100;

		public function Main():void{
			var ary:Array = new Array();
			var circleNum:int = 20;
			for (var i:Number = 0; i < circleNum; i++) {
				var sp:Sprite = new Sprite();
				sp.graphics.beginFill(Math.random() * 0xFFFFFF, Math.random());
				sp.graphics.drawCircle(Math.random() * sW, Math.random() * sH, Math.random() * radius);
				sp.graphics.endFill();
				sp.name = "Circle" + i;
				ary.push(sp);
				addChild(sp);
			}
		}
	}
}

제어는 아래를 참고

var temp:Sprite = getChildByName("Circle1");
(getChildByName("Circle"+i) as Sprite).x = 100; 

//Main.as
package  {

	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.*;
	import fl.motion.easing.*;
	import gs.TweenLite;

	public class Main extends Sprite {

		private var boxA:BoxA;
		private var boxB:BoxB;

		public function Main() {

			for (var i:int = 0; i < 3; i++) {
				boxA = new BoxA((i * 160) + 140, 60, "A" + i);
				boxA.addEventListener(MouseEvent.MOUSE_OVER, setBoxAMouseOverHandler);
				boxA.addEventListener(MouseEvent.MOUSE_OUT, setBoxAMouseOutHandler);
				addChild(boxA);
			}

			for (var j:int = 0; j < 3; j++) {
				boxB = new BoxB((j * 160) + 140, 140, "B" + j);
				boxB.addEventListener(MouseEvent.MOUSE_OVER, setBoxBMouseOverHandler);
				boxB.addEventListener(MouseEvent.MOUSE_OUT, setBoxBMouseOutHandler);
				addChild(boxB);
			}

		}

		private function setBoxAMouseOverHandler(e:MouseEvent):void {
			var _targetName:String = "B" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 1.2, 1.2);
		}

		private function setBoxAMouseOutHandler(e:MouseEvent):void {
			var _targetName:String = "B" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 1, 1);
		}

		private function setBoxBMouseOverHandler(e:MouseEvent):void {
			var _targetName:String = "A" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 1.2, 1.2);
		}

		private function setBoxBMouseOutHandler(e:MouseEvent):void {
			var _targetName:String = "A" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 1, 1);
		}

		private function tweenMotion(target:Object, duration:Number, sx:Number, sy:Number):void {
			TweenLite.to(target, duration, {scaleX:sx, scaleY:sy, ease:Elastic.easeOut } );
		}
	}
}

//BoxA
package {

	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.events.*;
	import fl.motion.easing.*;
	import gs.TweenLite;

	public class BoxA extends MovieClip{

		public function BoxA(_x:int, _y:int, _name:String) {
			x = _x;
			y = _y;
			name = _name;
			Num.text = _name;
			mouseChildren = false;
			buttonMode = true;
			addEventListener(MouseEvent.CLICK, setClickHandler);
		}

		private function setClickHandler(e:MouseEvent):void {
			tweenMotion(e.target, 0.5, 1);

			var _targetName:String = "B" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 0.5);
		}

		private function tweenMotion(target:Object, duration:Number, alpha:Number):void {
			TweenLite.to(target, duration, {alpha:alpha, ease:Elastic.easeInOut } );
		}
	}
}

//BoxB
package {

	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.events.*;
	import fl.motion.easing.*;
	import gs.TweenLite;

	public class BoxB extends MovieClip {

		public function BoxB(_x:int, _y:int, _name:String) {
			x = _x;
			y = _y;
			name = _name;
			Num.text = _name;
			mouseChildren = false;
			buttonMode = true;
			addEventListener(MouseEvent.CLICK, setClickHandler);
		}

		private function setClickHandler(e:MouseEvent):void {
			tweenMotion(e.target, 0.5, 1);

			var _targetName:String = "A" + e.target.name.substr(1, 1);
			var _target:MovieClip = e.target.root.getChildByName(_targetName);
			tweenMotion(_target, 0.5, 0.5);
		}

		private function tweenMotion(target:Object, duration:Number, alpha:Number):void {
			TweenLite.to(target, duration, {alpha:alpha, ease:Elastic.easeInOut } );
		}
	}
}

1. 내부 이용자 (자기 자신) – private
2. 계승 이용자 (서브급) – protected
3. 외부 이용자 (동일 package의 제3자) – internal
4. 외부 이용자 (다른 package의 제3자) – public

즉, 상속된 것인가? 같은 Package인가? 에 따라 2X2의 4종류로 나뉘게 된다.

그럼 간단한 예를 통해 알아보자.

package x {
    public class A {
        private var v1:int;
        protected var v2:int;
        internal var v3:int;
        public var v4:int;

        public function A() {
            v1 = 1; // OK
            v2 = 2; // OK
            v3 = 3; // OK
            v4 = 4; // OK
        }
    }
}

자기 자신에 대해서는 모두 OK

package x {
    public class B extends A {
        public function B() {
            v1 = 1; // Error
            v2 = 2; // OK
            v3 = 3; // OK
            v4 = 4; // OK
        }
    }
}

동일 Package내에서의 상속의 경우
- private : Error //자기 자신이 아니기 때문에 접근불가
- protected : OK //상속되었기 때문에 접근가능
- internal : OK //동일 Package이기 때문에 접근가능
- public : OK //접근가능

package x {
    public class C {
        public function C() {
            var a:A = new A();
            a.v1 = 1; // Error
            a.v2 = 2; // Error
            a.v3 = 3; // OK
            a.v4 = 4; // OK
        }
    }
}

동일 Package내에서의 다른 클래스(제3자)의 경우
- private : Error //자기 자신이 아니기 때문에 접근불가
- protected : Error //상속되지 않았기 때문에 접근불가
- internal : OK //동일 Package이기 때문에 접근가능
- public : OK //접근가능

package y {
    import x.A;
    public class D extends A {
        public function D() {
            v1 = 1; // Error
            v2 = 2; // OK
            v3 = 3; // Error
            v4 = 4; // OK
        }
    }
}

다른 Package에서 상속받은 경우
- private : Error //자기 자신이 아니기 때문에 접근불가
- protected : OK //상속되었기 때문에 접근가능
- internal : Error //동일 Package가 아니기 때문에 접근불가
- public : OK //접근가능

package y {
    import x.A;
    public class E {
        public function E() {
            var a:A = new A();
            a.v1 = 1; // Error
            a.v2 = 2; // Error
            a.v3 = 3; // Error
            a.v4 = 4; // OK
        }
    }
}

다른 Package에서 상속받지 않은 경우
- private : Error //자기 자신이 아니기 때문에 접근불가
- protected : Error //상속되지 않았기 때문에 접근불가
- internal : Error //동일 Package가 아니기 때문에 접근불가
- public : OK //접근가능

임기응변적인 방식으로, 처음에는 전부 private로 두고, 어디에서 사용될지에 의해 protected→internal→public으로 수정하는 방법이 있겠지만,
구현시에 컴파일 에러를 통해 수정하는 것은 시간도 오래 걸릴것이고 그다지 추천할만한 것은 아니다.
결국, 어떤 클래스로 구성 할 것인가, 어떠한 패키지로 구성 할 것인가에 대한 빈틈없는 설계가 중요한 것이 될 것이다.

//오브젝트의 반복 처리를 실행

var myObj:Object = {x:20, y:30};
for each (var num in myObj) {
 trace (num);
}

//출력 :
// 20
// 30

//XML 또는 XMLList 오브젝트의 반복 처리를 실행. 

var myXML:XML =
Jane
Susan
John
;
for each (var item in myXML.fname) {
 trace(item);
}

//출력
//Jane
//Susan
//John

//배열의 엘리먼트의 반복 처리를 실행할 수도 있음.

var myArray:Array = ["one", "two", "three"];
for each (var item in myArray) {
 trace (item);
}

//출력 :
// one
// two
// three