대상이 되는 메소드는 getURL(), loadMovie(), loadVariables()등의 함수이다.
이 함수들을 사용할 때는 on핸들러(키 또는 버튼에 의한 이벤트) 안에서 사용해야 한다.

on (press){
	getURL("http://www.domain.com/");
}

그리고, 하나의 on핸들러(키 또는 버튼에 의한 이벤트)에서는 외부와의 통신이 한번만 가능하다.
아래와 같이 하나 이상의 통신처리를 실행하게 되면 먼저 실행된 통신만 처리된다.

on (press){
	loadMovie("a.swf");
	loadMovie("b.swf");
}

loadMovie()에 대해서 잠깐…
Flash Lite 1.1은 Flash 4에 해당하는 액션스크립트이기 때문에 외부이미지는 로드하지 못한다. 오직, swf파일만 로드할 수가 있다.

그리고 loadVariables()로 PHP나 CGI등과 연계해서 반환 값을 가져올 수 있다.
하지만, loadVariables()를 사용할 때 주의해야 할 것이 있다. 먼저 loadVariables()을 사용할 때 HTTP메소드를 지정할 경우, au와 SoftBank의 일부 기종에서는 POST통신이 되지 않는 경우가 있기 때문에 특별한 이유가 없는 한 GET통신을 하는 것이 좋다.

on (press) {
	loadVariables("db.php", _root, "GET");
}

그리고, PHP에서 주의해야 할 것은 헤더를 출력하지 않으면 au에서는 정상적으로 처리되지 않는다.

<?php
	header("Content-type:text/plain");
?>

그 외에, loadVariables()로 외부 텍스트를 불러올 수도 있다.
단, XML형식은 지원되지 않기 때문에 아래와 같은 방법으로 사용한다.

변수1=값1&변수2=값2&변수3=값3&……%eof=1

위의 eof변수는 Flash Lite 1.1에서 외부 텍스트 파일을 어느 정도 불러왔는지에 대한 진행상황을 알 수 없어서, 반복처리를 통해 eof의 변수가 1이라면 로드가 완료되었다는 것을 알기 위한 변수이다.

fscommand2("FullScreen", true);
fscommand2("SetQuality", "high");
_focusrect = false;

이렇게 3줄이다.

첫번째줄의 fscommand2(”FullScreen”, true);는, 컨텐츠의 표시영역을 전체화면으로 표시하게 한다.
핸드폰에서는 기본적으로 전체화면으로 보여지도록 설정되어 있지만, 확실하게 해 두기 위해서 기술해준다.

두번째줄의 fscommand2(”SetQuality”, “high”);는 애니메이션의 렌더링품질을 설정한다.
high, medium, low의 3단계가 있다. high로 설정하면 품질은 좋아지지만, 복잡한 애니메이션의 경우 부하가 걸리기 때문에 해당 무비의 성격에 따라 적당한 값을 선택하는 것이 좋다.

세번째줄의 _focusrect = false;는 버튼포커스의 설정이다.
Flash Lite의 경우는 기본적으로 마우스가 없다. 대신 방향키(상,하)로 화면에 배치된 버튼을 선택하게 되는데, 버튼이 선택되면 해당 버튼의 테두리가 노란색으로 표시된다.
하지만, 대부분의 경우 버튼을 만들게 되면 롤오버효과도 디자인해서 적용하기 때문에 노란색 테두리가 없어도 현재 선택되어진 버튼이 어떤 버튼인지 쉽게 알 수 있다. 따라서 이 기능이 필요없기 때문에 false 로 설정한다.

“인라인재생”은 PC사이트에서와 같은 방법으로 HTML페이지에 swf파일을 표시하고 HTML페이지에 접속하는 방법이다.(예:http://mobilesite.com/flash.html)
“인라인재생”을 사용하면 swf에서 키이벤트를 사용할 수 없다. 그렇기 때문에 애니메이션 위주로 제작된 swf를 보여줄 때 주로 사용한다. 그리고, HTML페이지에 swf파일을 표시할 때 기본적으로 1개의 swf파일을 표시하는 것이 좋다. swf파일을 1개 이상 표시할 수 있는 기종도 있지만, 그 수가 그다지 많지 않기 때문이다.
여기서 잠깐, 모바일에서는 HTML에 어떤 코드로 swf를 삽입하는지 알아보자.
크게 다른 부분은 없고, 다른 부분은 src 를 data로 쓰는 정도이다.

<object width="180" height="50" type="application/x-shockwave-flash">
<param name="bgcolor" value="ffffff" />
<param name="loop" value="on" />
<param name="quality" value="high" />
</object>

각 항목의 내용은 다음과 같습니다.

・data：swf파일의 경로와 파일명
・width：가로사이즈
・height：세로사이즈
・bgcolor：swf파일의 배경색
・loop：반복재생의 유무(on/off)
・quality：화질의 설정(high/medium/low)의 3단계

“인터랙티브재생”은 swf파일에 직접 접속하는 방법이다.
(예:http://mobilesite.com/flash.swf)
“인터랙티브재생”은 키이벤트를 사용할 수 있기 때문에 게임과 같은 인터렉티브한 컨텐츠 제작하여 표시할 때 주로 사용한다.
키이벤트에는 다음의 종류가 있다.
- 방향키(상/하)
- 선택키
- 다이얼키(0~9, #, *)
참고로, 좌,우 방향키는 브라우저의 뒤로, 앞으로 의 기능으로 사용되고 있기 때문에 사용할 수 없다. (SoftBank의 기종에서는 모든 방향기(상,하,좌,우)를 사용할 수 있지만, 다른 기종을 고려해 볼 때 좌,우 방향키는 사용하지 않는것이 좋을 것이다.)

▶ 용랑은 100KB미만으로

현재 대부분의 핸드폰이 swf파일의 용량을 100KB까지 지원하고 있다.
그리고 모바일의 CPU는 일반PC의 CPU보다 처리 속도가 낮기 때문에 FPS를 10~12정도로 잡아주는 것이 좋다.

여기서 잠깐 참고 (FlashLite에서 용량을 줄이는 몇가지 팁을 소개하고 있다.)
- ケータイFlashコンテンツの容量を激減させ
るチェックリスト

▶ 무비클립 접근방법

//AS2.0의 경우
_root.my_mc.sub_mc.gotoAndPlay("Start");

//FlashLite1.1의 경우
tellTarget("/my_mc/sub_mc"){
	gotoAndPlay("Start");
}

▶ 속성 접근방법

//AS2.0의 경우
_root.my_mc.sub_mc._x = 100;

//FlashLite1.1의 경우
/my_mc/sub_mc/:_x = 100;

//또는
tellTarget("/my_mc/sub_mc"){
	_x = 100;
}

▶ 변수 접근방법

//AS2.0의 경우
_root.my_mc.sub_mc.myVar = 100;

//FlashLite1.1의 경우
/my_mc/sub_mc/:myVar = 100;

//또는
tellTarget("/my_mc/sub_mc"){
	myVar  = 100;
}

▶ function() 은 call(frame) 으로

FlashLite1.1 에서는 function을 사용할 수 없다. 그 대신 call()함수를 사용하면 OK
먼저 함수를 적어놓을 타임라인의 프레임에 라벨을 적어준다.
예를들어, callFunc 라는 라벨이 적힌 프레임에 아래와 같은 함수를 적어놓는다.

trace("[call Function]");

j = 0;

for(i = 1; i <= 10; i++){
	j = j + i;
	trace(j);
}

그리고 위의 함수를 호출하고 싶은 곳에서

call("callFunc");

결과는

[call Function]
1
3
6
10
15
21
28
36
45
55

▶ 디바이스 폰트의 사이즈

FlashLite1.1 에서 지원되는 디바이스 폰트의 사이즈는 12px, 16px, 20px, 24px이다.

▶ eval() 함수를 많이 써먹자

FlashLite1.1 에는 배열이 없다.
하지만, eval()을 이용하면 배열 에뮬레이션이 가능하다.

좀 더 자세한 내용은 아래링크를...

eval() 함수 사용 - http://livedocs.adobe.com/flash/9.0_kr/main/00005695.html
배열 에뮬레이션 - http://livedocs.adobe.com/flash/9.0_kr/main/00005690.html

▶ 이미지가 빨간색으로 보일 때

이미지를 사용했을 경우 Flash나 Device Central에서는 정상으로 보이는데, 핸드폰으로 직접 확인하면 이미지가 빨간색으로 보일 때가 있다.
주요 원인과 해결 방법은 다음과 같다.

- PNG파일을 사용했을 경우
→ 라이브러리에서 해당 PNG파일의 압축을 lossless (PNG/GIF) 로 한다.

- SWF의 용량이 100KB를 넘거나 간당간당 할 경우.
→ 용량을 줄여준다.

- 메모리를 점유율이 높을 때
→ 비트맵 이미지 사용을 줄인다.
→ trace()를 삭제한다.
→ 선의 사용을 줄인다.
→ 변수가 필요없게 되었을 경우 null을 대입한다.

- 그라데이션이 있는 투명PNG파일을 사용했을 경우
→ 그라데이션을 없애준다.

Publish Settings 의 Flash 탭에 있는 옵션사항인데, 이 항목을 체크하면 Publish 할 때 trace() 구문을 지워준다.
실제로 플래시에서 작업하면서 이런저런 디버깅을 하기 위해 trace()를 사용하는데, 최종적으로 Publish할때는 필요없게 된다.
이럴 때 요놈을 체크해주면 Publish 할 때 소스의 trace()구문들을 싹 지워준다.

뭐, 지워도 그만이고.. 안 지워도 그만이라면 상관없지만, 이 기능으로 추가적으로 얻을 수 있는 것이 바로 “용량”이다.
trace()구문을 무지하게 사용한 경우(나의 경우 뭐 하나 생각대로 안 움직이면 trace()를 여기저기 찍어덴다;;),
Omit trace actions 에 체크만 해 주면 꽤 짭짤한 용량을 절약할 수 있게 된다.

웹에서 사용하는 무비라면 크게 감동받을 정도는 아니지만,
용량의 제한을 크게 받는 모바일이나 배너의 경우에는 큰 도움이 된다.

random_num = 3;    //랜덤으로 가져올 데이터 수

text_1 = "TEXT-01";
text_2 = "TEXT-02";
text_3 = "TEXT-03";
text_4 = "TEXT-04";
text_5 = "TEXT-05";
text_6 = "TEXT-06";
text_7 = "TEXT-07";
text_8 = "TEXT-08";
text_9 = "TEXT-09";
text_10 = "TEXT-10";
text_11 = "TEXT-11";
text_12 = "TEXT-12";
text_13 = "TEXT-13";
text_14 = "TEXT-14";
text_15 = "TEXT-15";

order_num = "ABCDEFGHIJKLMNO";    //전체 데이터의 수(15개)

for (i = 1; i <= _root.random_num; i++) {
    rn = random(length(order_num)) + 1;
    _root["n" add i] = substring(order_num, rn, 1);
    if (rn == 1) {
        order_num = substring(order_num, 2, length(order_num));
    }
    else {
        a_txt = substring(order_num, 1, rn - 1);
        b_txt = substring(order_num, rn + 1, length(order_num));
        order_num = a_txt add b_txt;
    }
    _root["n" add i] = ord(_root["n" add i]) - 64;
    textData = eval("text_" add _root["n" add i]);
    trace("textData = " add textData);
}

아스키코드 표